不等分散下での母平均の対比較に対する多重性調整法

MIXED Procedure の lsmeans statement

不等分散下での母平均の対比較に対する多重性調整法としては、Tukey 型対比の Games–Howell と Dunnett's C、任意の対比の Tamhane's T2 や Dunnett's T3 などがある。 SAS は Games–Howell, Tamhane's T2, Dunnett's T3 に対応しており、MIXED Procedure の lsmeans statement を使うと調整 $P$ 値や調整信頼区間などが求められる。

  /* Unequal sample sizes and variances */
  data x;
  call streaminit(161013);
  do group = 1 to 3;
  do n = 1 to 5*group;
    y = rand("Normal", 1, group*2);
    output;
  end; end;
  run;


  /* Tamhane's T2 (comparisons with control) */
  proc mixed data = x;
  class group;
  model y = group / ddfm = satterth;
  repeated /group = group;
  lsmeans group / adjust = sidak adjdfe = row diff = control('1') cl;
  run;

  /* Dunnett's T3 (comparisons with control) */
  proc mixed data = x;
  class group;
  model y = group / ddfm = satterth;
  repeated / group = group;
  lsmeans group / adjust = smm adjdfe = row diff = control('1') cl;
  run;


  /* Games-Howell (comparisons with all pairs) */
  proc mixed data = x;
  class group;
  model y = group / ddfm = satterth;
  repeated / group = group;
  lsmeans group / adjust = tukey adjdfe = row cl;
  run;

  /* Tamhane's T2 (comparisons with all pairs) */
  proc mixed data = x;
  class group;
  model y = group / ddfm = satterth;
  repeated / group = group;
  lsmeans group / adjust = sidak adjdfe = row cl;
  run;

  /* Dunnett's T3 (comparisons with all pairs) */
  proc mixed data = x;
  class group;
  model y = group / ddfm = satterth;
  repeated / group = group;
  lsmeans group / adjust = smm adjdfe = row cl;
  run;
  

上記の方法を適用する場合は自由度推定方法のオプションには ddfm = satterth を指定しますが、一応 kr, kr2 も指定できるようです (一元配置の場合には違いはないと思われます)。
また、adjdfe = row を用いないと多重性の調整に用いる自由度が Type 3 の分母自由度の値に固定されてしまうので、必ず指定が必要。
反復の構造 repeated に group を指定し、group ごとに分散が異なるモデルを当てはめています (repeated は default では type = vc なので)。
残念ながら Dunnett's C や他の方法には対応していないようです。

各手法の特徴については Hochberg & Tamhane (1987) を参照するとよいでしょう。

参考文献

1. Hochberg Y, Tamhane AC. Multiple Comparison Procedures. New York: Wiley, 1987.

履歴

• 2016/10/13 公開